As partes principais das unidades de disco rígido são os pratos giratórios e os cabeçotes que lêem e gravam dados neles. A parte externa dessas travessas em forma de disco, graças ao que a física nos ensina, tem aceleração linear mais rápida. Além disso, há um custo de desempenho percebido quando os dados são espalhados por toda a superfície.
MyDefrag pode estar semi-extinto, mas continua sendo o único programa desse tipo que pode otimizar seu disco rígido exatamente da maneira que você deseja. Como todos os desfragmentadores, ele reorganiza todas as partes de seus arquivos, empacotando-os juntos, corrigindo o baixo desempenho quando espalhado por todo o problema superficial. Ele também permite que você configure zonas, colocando seus arquivos mais importantes na região externa mais rápida da superfície do HDD. Você apenas tem que dizer o que vai aonde por meio de um script simples.
Localize, baixe e instale MyDefrag
Infelizmente, MyDefrag não tem suporte hoje em dia, e seu site oficial está morto. Você ainda pode encontrá-lo, no entanto, em sites de hospedagem de software populares, como FileHippo e MajorGeeks.
Baixe e instale a última versão do programa, MyDefrag 4.3.1. Aceite todos os padrões durante a instalação e certifique-se de que “Selecionar e ativar o MyDefrag ScreenSaver” está desmarcado.
Crie um novo script
Você não controla como o MyDefrag opera por meio de uma interface gráfica ou opções de linha de comando – isso é feito com scripts simples. Localize os scripts da subpasta, que existem para essa finalidade em seu diretório de instalação.
Clique com o botão direito neste diretório e crie um novo arquivo TXT em branco. Dê a ele qualquer nome que desejar, mas altere sua extensão para “MyD,” o padrão para scripts MyDefrag. Em seguida, abra-o em seu editor de texto favorito.
Introdução do script
Usaremos os existentes como base para um script que otimiza um disco rígido repleto de jogos, colocando os arquivos que afetam seu desempenho mais do que outros nas partes mais rápidas da superfície do disco, movendo os menos essenciais e não com frequência dados acessados para a outra extremidade.
A primeira parte do seu script deve configurar as coisas da seguinte maneira. Observe que você deve colocar cada parâmetro e comando em uma linha nova e individual. Observe também que usaremos comentários no código – eles começam com “//” – para explicar as partes mais enigmáticas de nosso script.
Title("Title of your script")
Description("Short description of your script")
WriteLogfile("MyDefrag.log","LogHeader")
VolumeSelect
CommandlineVolumes()
VolumeActions
AppendLogfile("MyDefrag.log","LogBefore")
Configure sua primeira zona
Ao dividir a superfície do HDD em zonas, o MyDefrag permite que você coloque arquivos e pastas específicos nas partes de sua superfície que apresentam melhor ou pior desempenho.
Configure as zonas selecionando o que deve ser inserido nelas:
// Zone 1 - Non-important, slow files FileSelect // Select specific files. !include "file_list.txt"! // Select the files defined in file_list.txt. FileActions // What MyDefrag will do with those files. MoveToEndOfDisk() // Move them to slower portion of the HDD since they are the unimportant ones AddGap(ZoneEnd + VolumeFree * 0.1 // Add a 0.1% size gap between that zone and the next one FileEnd // End file selection for the specific zone
Configurando mais zonas
MyDefrag só pode empacotar seus arquivos, como outros desfragmentadores, se você não configurar nenhuma zona, mas você perderá todo o sentido de seu uso.
Configuramos mais zonas da seguinte maneira:
// Zone 2: Put directories together, for quicker listing of the HDD's contents - same syntax as before
FileSelect
Directory(yes) // Define that we want to select directories, not files.
FileActions
SortByName(Ascending) // Sort them by alphabetical order.
AddGap(ZoneEnd + VolumeFree * 0.05)
FileEnd
// Zone 3: Typical, popular "game filetypes", for quicker game launching
FileSelect
Filename("_.exe")
OR Filename("_.dll")
OR Filename("_.ini")
OR Filename("_.conf")
OR Filename("_.cfg")
OR Filename("_.bat")
OR Filename("_.ico")
FileActions
SortByName(Ascending)
AddGap(ZoneEnd + VolumeFree * 0.1)
FileEnd
// Zone 4: Place the MFT and other special NTFS files right after our most important files
FileSelect
SelectNtfsSystemFiles(yes)
FileActions
PlaceNtfsSystemFiles(Ascending,MftSize * 0.01) // Move the selected NTFS system files and set the MFT to a %0.01 size.
AddGap(ZoneEnd + VolumeFree * 0.01)
FileEnd
// Zone 5: Recently accessed files (for better performance of last games played).
FileSelect
LastAccessEnabled(yes) and LastAccess(60 days ago,now)
FileActions
SortByName(Ascending)
AddGap(ZoneEnd + VolumeFree * 0.3)
FileEnd
// Zone 6: all other files.
FileSelect
all
FileActions
SortByName(Ascending)
AddGap(ZoneEnd + VolumeFree)
FileEnd
Roteiro final
O que segue aqui é todo o roteiro final. Sinta-se à vontade para copiar e colar em seu próprio script e, em seguida, ajustá-lo como desejar.
Title("Routech.ro's Games HDD Monthly")
Description("Optimize Game HDDs by moving temp, downloading, and non-important gaming-related files and directories to its end, leaving the faster HDD space for more important stuff.")
// Write the header to the logfile. See the "Settings.MyD" file for the definition of the "LogHeader" string.
WriteLogfile("MyDefrag.log","LogHeader")
// Select and process the volumes one by one.
VolumeSelect
CommandlineVolumes()
VolumeActions
// Write the "before" statistics to the logfile. See the "Settings.MyD" file for the definition of the "LogBefore" string.
AppendLogfile("MyDefrag.log","LogBefore")
// Zone 1 - Place Non-important, temp and ultra-large files at the end of the disk.
FileSelect
!include "file_list.txt"!
FileActions
MoveToEndOfDisk()
AddGap(ZoneEnd + VolumeFree * 0.1)
FileEnd
// Zone 2: Directories.
FileSelect
Directory(yes)
FileActions
SortByName(Ascending)
AddGap(ZoneEnd + VolumeFree * 0.05)
FileEnd
// Zone 3: Main Game Files (for quicker game launch).
FileSelect
Filename("*.exe")
OR Filename("*.dll")
OR Filename("*.ini")
OR Filename("*.conf")
OR Filename("*.cfg")
OR Filename("*.BAT")
OR Filename("*.ico")
FileActions
SortByName(Ascending)
AddGap(ZoneEnd + VolumeFree * 0.1)
FileEnd
//Zone 4: Place the MFT and some other special NTFS files.
FileSelect
SelectNtfsSystemFiles(yes)
FileActions
PlaceNtfsSystemFiles(Ascending,MftSize * 0.01)
AddGap(ZoneEnd + VolumeFree * 0.01)
FileEnd
// Zone 5: Recently accessed files (for better performance of last games played).
FileSelect
LastAccessEnabled(yes) and LastAccess(60 days ago,now)
FileActions
SortByName(Ascending)
AddGap(ZoneEnd + VolumeFree * 0.3)
FileEnd
// Zone 6: all other files.
FileSelect
all
FileActions
SortByName(Ascending)
AddGap(ZoneEnd + VolumeFree)
FileEnd
// Write the "after" statistics to the logfile. See the "Settings.MyD" file for the definition of the "LogAfter" string.
AppendLogfile("MyDefrag.log","LogAfter")
VolumeEnd
// Write the footer to the logfile. See the "Settings.MyD" file for the definition of the "LogFooter" string.
AppendLogfile("MyDefrag.log","LogFooter")
Crie uma lista de arquivos de baixa prioridade
Lembra como dissemos ao nosso script para levar em consideração uma lista de arquivos de baixa prioridade, no formato TXT, antes de organizar nossos arquivos? Agora é a hora de criar esse arquivo.
Clique com o botão direito na pasta de scripts e crie um novo arquivo TXT em branco. Nomeie-o “file_list.txt” – o mesmo nome de arquivo que usamos no próprio script.
Aqui está um exemplo de lista que você pode copiar e usar. Altere os diretórios e arquivos para aqueles com os quais você não se importa.
DirectoryName("Game_I_never_play_after_installing")
OR DirectoryName("Another_game_I_keep_but_rarely_play")
OR DirectoryName("Game_that_takes_up_almost_half_the_HDD")
OR Filename("vc_redist.x64.exe")
OR Filename("vcredist_x64.exe")
OR Filename("vcredist_x64*.exe")
OR Filename("*.iso")
OR Filename("*.isz")
OR Filename("*.mdf")
OR Filename("*.cdi")
OR Filename("*.pdf")
OR Filename("*.bik")
OR Filename("*.avi")
OR Filename("*.wmv")
OR Filename("*.bk2")
OR Filename("*.mp4")
OR Filename("*.rar")
OR Filename("*.zip")
OR Filename("*.7z")
OR Filename("*.7z.*")
Execute seu script
Com os dois arquivos que definem sua lógica de desfragmentação prontos, é hora de colocá-los em prática! Execute MyDefrag e, se não houver erro de digitação em qualquer lugar, seu script deve aparecer entre os scripts padrão na lista do programa.
Selecione-o na lista “Selecionar um script”. Em seguida, como afirma MyDefrag, “Selecione 1 ou mais discos” da segunda lista que deseja desfragmentar com base nas regras do seu script. Clique em “Executar” e aguarde algumas horas (ou dias, para HDDs grandes com Terabyte) para fazer sua mágica funcionar.
É isso aí. Você desfragmentou e otimizou seu disco rígido da maneira que deseja, e ele deve estar funcionando melhor e mais rápido agora.
Relacionado:
- O que acontece quando você desfragmenta uma unidade?
- 5 ferramentas que melhoram o desempenho do disco rígido do Windows 10
- Como desfragmentar seus discos rígidos no menu de contexto do Windows
